hp41programs

COSMO2

Cosmology(II) for the HP-41


Overview
 

 1°)  Empty Universes
 2°)  Einstein's & Godel's Universes
 3°)  Oscillating Universes
 4°)  Tolman Universes
 5°)  Other Cyclic Universes without Singularity
 
 
 

1°) Empty Universes
 

-This program summarizes several routines listed in "General Relativity & Cosmology" ( cf this page for the formulae )

-Given the cosmological parameter Lambda = L0  and the the redshift z of a galaxy or a quasar , "CSM" computes

   D  = light-time distance                          t0 = Age of the Universe                  R0  = Radius of the Universe                            k = +1  for spherical Universes
   D0 = comoving radial distance               P = Period of the Universe              Rmin = minimum radius of the universe               k =  0   for Euclidean Universes
   DL = luminosity-distance                                                                              Rmax = maximum radius of the universe             k = -1   for hyperbolic Universes

   and the recessional velocity VR  ( speed of light = 1 )

-All the distances are expressed in light-years
-All the times are expressed in years
 

Remark:
 

-The Hubble's constant has been chosen such that:    1 / H0 = 1.377 E10  years ( line 227 )
-Change this line if you want to use another value.
 

Data Registers:             R00 = VR  ( c = 1 )

                                        R01 = D               R04 = t0             R06 = R0               R09 = k ( -1 , 0 , +1 )
                                        R02 = D0             R05 = P             R07 = Rmin
                                        R03 = DL                                       R08 = Rmax

                                     ( R10 = z    R11 = z + 1    R12 = L0    R13 & R14: temp )
Flag:  F24
Subroutines: /
 

-Lines 66 and 84 are three-byte GTO 04
 
 

  01  LBL "CSM"
  02  DEG
  03  STO 10      
  04  1
  05  +
  06  STO 11
  07  X<>Y
  08  STO 12
  09  1
  10  -
  11  STO 04 
  12  RCL 12 
  13  X=0?
  14  SIGN
  15  /
  16  ABS
  17  SQRT
  18  STO 13
  19  *
  20  STO 14
  21  CLX
  22  STO 05
  23  STO 07
  24  90 
  25  TAN
  26  STO 08
  27  SIGN
  28  CHS
  29  STO 09
  30  RCL 12
  31  ABS
  32  SQRT
  33  X=0?
  34  SIGN
  35  1/X
  36  STO 01
  37  X<> 04
  38  ABS
  39  SQRT
  40  X=0?
  41  SIGN
  42  1/X
  43  STO 00      
  44  STO 02
  45  STO 03
  46  STO 06 
  47  SIGN
  48  RCL 12
  49  X#0?
  50  GTO 00
  51  RCL 10
  52  RCL 11
  53  1
  54  +
  55  *
  56  2
  57  / 
  58  STO 03
  59  RCL 11 
  60  LN
  61  STO 00
  62  STO 02 
  63  RCL 10
  64  RCL 11
  65  / 
  66  GTO 04
  67  LBL 00
  68  X<0?
  69  GTO 01
  70  X#Y?
  71  GTO 02
  72  CLX
  73  STO 09
  74  RCL 10
  75  STO 00 
  76  STO 02
  77  RCL 11      
  78  *
  79  STO 03
  80  RCL 08
  81  STO 04 
  82  LASTX
  83  LN
  84  GTO 04
  85  LBL 01
  86  PI
  87  RCL 01
  88  *
  89  STO 05 
  90  RCL 06 
  91  RCL 13
  92  *
  93  STO 08
  94  RCL 14
  95  ENTER
  96  X^2
  97  1
  98  -
  99  SQRT
100  +
101  RCL 13
102  ENTER
103  X^2
104  1
105  -
106  SQRT
107  +
108  /
109  LN
110  ST* 00
111  ST* 02
112  E^X-1
113  LASTX
114  CHS
115  E^X-1
116  -
117  2
118  /
119  RCL 11      
120  *
121  ST* 03
122  RCL 13
123  1/X
124  ASIN
125  D-R
126  ST* 04
127  RCL 14
128  1/X
129  ASIN
130  D-R
131  -
132  GTO 04
133  LBL 02
134  X>Y?
135  GTO 03
136  RCL 14
137  ENTER
138  X^2
139  1
140  +
141  SQRT
142  +
143  RCL 13      
144  ENTER
145  X^2
146  1
147  +
148  SQRT
149  +
150  /
151  LN
152  ST* 00
153  ST* 02
154  E^X-1
155  LASTX
156  CHS
157  E^X-1
158  -
159  2
160  /
161  RCL 11 
162  *
163  ST* 03
164  RCL 13
165  1/X
166  ENTER
167  X^2
168  1
169  +
170  SQRT
171  +
172  LN
173  ST* 04
174  RCL 14
175  1/X
176  ENTER
177  X^2
178  1
179  +
180  SQRT
181  +
182  LN
183  -
184  GTO 04
185  LBL 03
186  X<>Y
187  STO 09      
188  RCL 13
189  ACOS
190  RCL 14
191  ACOS
192  -
193  D-R
194  ST* 00
195  ST* 02
196  LASTX
197  SIN
198  RCL 11 
199  *
200  ST* 03
201  RCL 06
202  RCL 13
203  *
204  STO 07
205  LASTX
206  1/X
207  ENTER
208  X^2
209  1
210  -
211  SQRT
212  +
213  LN
214  ST* 04
215  RCL 14      
216  1/X
217  ENTER
218  X^2
219  1
220  -
221  SQRT
222  +
223  LN
224  -
225  LBL 04
226  SF 24
227  1377 E7
228  ST* 02
229  ST* 03
230  ST* 04
231  ST* 05
232  ST* 06
233  ST* 07
234  ST* 08
235  *
236  ST* 01
237  CF 24
238  RCL 09 
239  RCL 06
240  RCL 04
241  RCL 01
242  END

 
     ( 289 bytes / SIZE 015 )
 
 

      STACK        INPUTS      OUTPUTS
           T             /           k
           Z             /           R0
           Y           L0            t0
           X            z            D

 
Example:     With   z = 7  , here are the results given for 5 L-values   ( except  z = 0.3 if  L0 = 1.4 )
 
 
 

       L0      -0.4         0     +0.4         1       1.4      units   Registers
       D    1.0823    1.2049    1.4013    2.8634    0.3877    x E10      R01
       D0    2.5125    2.8634    3.4598    9.6390    0.4448    x E10      R02
       DL    3.9784    4.3376    4.8774    7.7112    0.5743    x E11      R03
       t0    1.2278     1.3770    1.6231     infinity    1.4419    x E10      R04
       P    6.8400        0        0        0         0    x E10      R05
       R0    1.1638    1.3770    1.7777    1.3770    2.1772    x E10      R06
      Rmin        0        0        0        0    1.1638    x E10      R07
      Rmax    2.1772    infinity    infinity    infinity    infinity    x E10      R08
       k       -1       -1       -1        0       +1      x 1      R09
      VR     1.8246    2.0794    2.5125        7    0.3230      x 1      R00

 
Notes:

-"CSM" always stops at the last line.
-"infinity" is actually displayed 9.999999999 E99

-The period P only exists if the cosmological parameter L0 is negative
-The maximum radius Rmax is finite only if L0 < 0.  In this case, we have a pulsating Universe with a big bang & a big crunch

-The minimum radius Rmin is positive ( > 0 ) only if L0 > 1
 

->  t0   P   R0   Rmin    Rmax   and  k  are of course independant from z
 

2°) Einstein's & Gödel's Universes
 

-The first version of Einstein's Universe was a static Spherical Universe.
-The radius R of the Universe is related to the cosmological constant Lambda and the mean density (rho) by

      Lambda = 4 Pi G (rho) / c2                            where  G  is the gravitational constant
           R      = 1 / SQRT(Lambda)                         and    c  is the speed of light

-K. Gödel found a rotating - but non expanding - Universe where the metric is defined by

     ds2 = a2 [ ( dx0 + exp x1 dx2 )2 - ( dx1 )2 - (1/2) exp 2.x1 ( dx2 )2 - ( dx3 )2 ]      where  a  is a constant

-Assuming the pressure p = 0 , Einstein's equations lead to

      Lambda = -1 / ( 2.a2 )  = - 4 Pi G (rho) / c2    and the period T of rotation of the matter is given by
           T      =  2 Pi / omega  with  omega = [ 4 Pi G (rho) ]1/2

-"EINGD" takes the mean density (rho) and returns the main constants above
 

Data Registers: /

Flag:  F01   CF 01 =  Einstein's Universe
                    SF 01  =  Gôdel's Universe

Subroutines: /
 
 

 01  LBL "EINGD"
 02  STO M
 03  21156
 04  *
 05  ABS
 06  SQRT
 07  1/X
 08  FS? 01
 09  GTO 00
 10  DEG
 11  90
 12  TAN
 13  LBL 00
 14  RCL M
 15  835206
 16  *
 17  FS? 01
 18  CHS
 19  ENTER^
 20  ABS
 21  FS? 01
 22  ST+ X
 23  SQRT
 24  1/X
 25  0
 26  X<> M
 27  SIGN
 28  RDN
 29  END

 
( 57 bytes / SIZE 000 )
 
 

       STACK         INPUT  CF01 OUTPUTS SF01 OUTPUTS
            T             /         k = +/-1        k = +/-1
            Z             /              T             T
            Y             /         Lambda         Lambda
            X      rho ( kg/m3 )              R             a
            L             /             rho            rho

                    R  is expressed in light-years
  Where   Lambda is expressed in (light-years) -2             k = +1 for a spherical Universe or -1 for a hyperbolic Universe
                    T  is expressed  in years

Example:   If  rho =  3.14 10 -28 kg/m3

     •  Einstein's Universe CF 01

        CF 01
     3.14 E-28  XEQ "EINGD"  >>>>    R   =  6.1750  E10   l-y
                                                RDN   Lam =  2.6225 E-22 (l-y) -2
                                                RDN     T   =  9.9999  E99  years   ( no rotation )
                                                RDN     k   =  +1
 

     •  Gödel's Universe SF 01

        SF 01
     3.14 E-28  XEQ "EINGD"  >>>>    a   =   4.3664  E10   l-y
                                                RDN   Lam =  -2.6225 E-22 (l-y) -2
                                                RDN     T   =   3.8799  E11  years   ( period )
                                                RDN     k   =  +1

Notes:

-Though it's probably not realistic, "EINGD" may also be used with a negative density, for example:

       CF 01
   -3.14 E-28  XEQ "EINGD"  >>>>    R   =    6.1750  E10   l-y
                                                RDN   Lam =  -2.6225 E-22 (l-y) -2
                                                RDN     T   =  9.9999  E99  years   ( no rotation )
                                                RDN     k   =  -1

-With rho < 0 , Einstein's Universe becomes hyperbolic and stable

-David F. Crawford has created an alternative cosmology, "Curvature Cosmology" where a static spherical Universe is stable too !
-It's a tired-light model. ( cf reference [3] )
 

3°)  Oscillating Universes
 

-This program supposes that there is only a negative cosmological parameter Lambda and a radiation parameter ¶ ( matter-density = 0 )
-Though it's "probably" not realistic, it gives examples of pulsating universes without any singularity.

-As before, Einstein's equations are used.
 
 

Data Registers:             R00 = k  ( -1 , 0 , +1 )

                                        R01 = D             R04 = R0             R07 = zmin < 0              R10 = Lambda < 0
                                        R02 = t0             R05 = Rmin         R08 = zmax                     R11 = ¶
                                        R03 = P             R06 = Rmax         R09 = z                          R12 = ¶ / Lambda
Flags: /
Subroutines: /
 
 

  01  LBL "PULSE"
  02  DEG
  03  STO 09         
  04  X<> Z
  05  STO 11 
  06  X<>Y
  07  STO 10 
  08  /
  09  STO 12
  10  LASTX
  11  RCL 11
  12  +
  13  1
  14  -
  15  STO 00
  16  RCL 10
  17  ST+ X
  18  /
  19  CHS
  20  STO 04
  21  CHS
  22  ENTER
  23  X^2
  24  RCL 12
  25  -
  26  SQRT
  27  RCL Y
  28  SIGN
  29  *
  30  +
  31  X#0?
  32  ST/ Y
  33  X<0?
  34  CLX
  35  X<>Y
  36  X<0?
  37  CLX
  38  X>Y?
  39  X<>Y
  40  SQRT
  41  STO 05         
  42  X=0?
  43  GTO 00
  44  1/X
  45  1
  46  -
  47  GTO 01
  48  LBL 00
  49  CLX
  50  90
  51  TAN
  52  LBL 01
  53  X<>Y
  54  SQRT
  55  STO 06 
  56  1/X
  57  1 
  58  -
  59  X>Y?
  60  X<>Y
  61  STO 07
  62  X<>Y
  63  STO 08
  64  1
  65  STO Y
  66  RCL 04
  67  ST+ Y
  68  X^2
  69  RCL 12         
  70  -
  71  SQRT
  72  STO 03 
  73  /
  74  ASIN
  75  RCL 04
  76  RCL 09
  77  1
  78  +
  79  X^2
  80  1/X
  81  +
  82  RCL 03
  83  /
  84  ASIN
  85  -
  86  D-R
  87  X<>Y
  88  RCL 05 
  89  X>0?
  90  GTO 00
  91  CLX
  92  RCL 08
  93  1
  94  +
  95  1/X
  96  X^2
  97  RCL 04
  98  +
  99  RCL 03         
100  /
101  ASIN
102  GTO 01
103  LBL 00
104  CLX
105  90
106  CHS
107  LBL 01
108  STO 03
109  -
110  D-R
111  90
112  RCL 03
113  -
114  D-R
115  ST+ X
116  STO 03
117  CLX
118  RCL 00 
119  X#0?
120  SIGN
121  X<> 00
122  ABS
123  SQRT
124  X=0?
125  SIGN
126  1/X
127  STO 04         
128  ST* 05
129  ST* 06
130  X<> Z
131  RCL 10 
132  CHS
133  SQRT
134  ST+ X
135  ST/ 03
136  ST/ Z
137  /
138  1377 E7
139  ST* 03
140  ST* 04
141  ST* 05
142  ST* 06
143  ST* T
144  ST* Z
145  *
146  STO 01
147  X<>Y
148  STO 02
149  X<>Y
150  RCL 03 
151  SIGN
152  CLX
153  RCL 00
154  RDN
155  END

 
         ( 197 bytes / SIZE 013 )
 
 

      STACK        INPUTS      OUTPUTS
           T             /           k
           Z           ¶0           R0
           Y        L0 < 0            t0
           X            z            D
           L            /            P

  where the distances are expressed in light-years and the times in years

Example:    With   ¶0 = -0.0001  ,   L0 = -0.1  ,  z = 10

      -0.0001  ENTER^
         -0.1     ENTER^
           10     XEQ "PULSE"   >>>>   D  = 1.2148    E10  l-y     = R01
                                               RDN    t0 =  1.3336   E10  years = R02
                                               RDN   R0 =  1.3129   E10  L-y   = R04
                                               RDN    k  =   -1                          = R00
                                            LASTX   P  =  1.3680   E11 years = R03

 And we also have:

    R05 =  Rmin =  1.2517   E08  l-y
    R06 =  Rmax =  4.3544   E10 l-y
    R07 =  zmin  =  -0.6985
    R08 =  zmax  =  103.8852

-So, this universe is hyperbolic and its radius oscillates between  Rmin =  1.2517   E08  l-y  and  Rmax =  4.3544   E10 l-y
-The period between 2 minima or 2 maxima is P  =  1.3680   E11 years
 

  R
   |
   |                    *                                        *
   |              *          *                           *            *
   |           *                *                     *                  *
   |       *                       *               *                        *
   |*                                      *                                        *
   |-------------------------- P--------------------------2P---------------------------- t
 
 

4°)  Tolman Universes
 

-This program put together the program just above ( PULSE )
  + TOL ( listed in "General Relativity & Cosmology" §3-f-1 )
  + the case Lambda = 0

-Here,  (Omega)mat = 0
 

Data Registers:             R00 = k  ( -1 , 0 , +1 )

                                        R01 = D             R04 = R0             R07 = zmin < 0              R10 = Lambda
                                        R02 = t0             R05 = Rmin         R08 = zmax                     R11 = ¶
                                        R03 = P             R06 = Rmax         R09 = 1/(z+1)^2            R12 = ¶ / Lambda
Flags: F10-F24
Subroutines: /

-Lines 28-41-138 are three-byte GTO's
 
 

  01  LBL "TOL"
  02  DEG
  03  1
  04  +
  05  1/X
  06  X^2
  07  STO 09        
  08  RDN
  09  STO 10
  10  X<>Y
  11  STO 11 
  12  +
  13  1
  14  -
  15  STO 00
  16  90
  17  TAN
  18  STO 03
  19  STO 06
  20  STO 08
  21  CHS
  22  STO 07
  23  CLX
  24  STO 05
  25  RCL 11
  26  RCL 10
  27  X=0?
  28  GTO 03
  29  CF 10
  30  X<0?
  31  SF 10
  32  /
  33  STO 12
  34  RCL 00
  35  RCL 10
  36  ST+ X
  37  /
  38  CHS
  39  STO 04
  40  FC?C 10
  41  GTO 04
  42  CHS
  43  ENTER
  44  X^2
  45  RCL 12        
  46  -
  47  SQRT
  48  RCL Y
  49  SIGN
  50  *
  51  +
  52  X#0?
  53  ST/ Y
  54  X<0?
  55  CLX
  56  X<>Y
  57  X<0?
  58  CLX
  59  X>Y?
  60  X<>Y
  61  SQRT
  62  STO 05 
  63  X=0?
  64  GTO 00
  65  1/X
  66  1
  67  -
  68  GTO 01
  69  LBL 00
  70  CLX
  71  RCL 06
  72  LBL 01
  73  X<>Y
  74  SQRT
  75  STO 06
  76  1/X
  77  1
  78  -
  79  X>Y?
  80  X<>Y
  81  STO 07
  82  X<>Y
  83  STO 08
  84  1
  85  STO Y
  86  RCL 04
  87  ST+ Y
  88  X^2
  89  RCL 12
  90  -
  91  SQRT
  92  STO 03        
  93  /
  94  ASIN
  95  STO Y
  96  RCL 04
  97  RCL 09
  98  +
  99  RCL 03 
100  /
101  ASIN
102  -
103  D-R
104  X<>Y
105  RCL 05
106  X>0?
107  GTO 00
108  CLX
109  RCL 08
110  1
111  +
112  1/X
113  X^2
114  RCL 04
115  +
116  RCL 03
117  /
118  ASIN
119  GTO 01
120  LBL 00
121  CLX
122  90
123  CHS
124  LBL 01
125  STO 03
126  -
127  D-R
128  90
129  RCL 03
130  -
131  D-R
132  ST+ X
133  STO 03
134  RDN
135  STO 02 
136  X<>Y
137  STO 01
138  GTO 05
139  LBL 03
140  SIGN
141  RCL 11        
142  RCL 00
143  X=0?
144  GTO 00
145  RCL 09
146  *
147  -
148  SQRT
149  -
150  STO 01
151  CLX
152  RCL 11
153  X<0?
154  FS? 30
155  GTO 01
156  RCL 00
157  /
158  SQRT
159  STO 05
160  1/X
161  1
162  STO 02
163  -
164  STO 08
165  GTO 03
166  LBL 01
167  SQRT
168  -
169  STO 02
170  LBL 03
171  RCL 00
172  CHS
173  ST/ 01
174  ST/ 02
175  RCL 00
176  X<0?
177  GTO 05
178  RCL 11
179  RCL 00 
180  /
181  SQRT
182  STO 06
183  1/X
184  1
185  -
186  STO 07
187  RCL 11        
188  SQRT
189  ST+ X
190  RCL 00
191  /
192  STO 03
193  GTO 05
194  LBL 00
195  2
196  1/X
197 STO 02
198  1
199  RCL 09
200  -
201  *
202  STO 01
203  GTO 05
204  LBL 04
205  1
206  +
207  ENTER
208  X^2
209  RCL 04
210  X^2
211  -
212  RCL 12
213  +
214  SQRT
215  +
216  ABS
217  LN
218  STO 01
219  RCL 04
220  X^2
221  RCL 12
222  -
223  X<0?
224  GTO 00
225  SQRT
226  STO 02 
227  RCL 04
228  -
229  X<=0?
230  GTO 00
231  SQRT
232  STO 05        
233  1/X
234  1
235  -
236  STO 08
237  CLX
238  RCL 02
239  GTO 01
240  LBL 00
241  CLX
242  RCL 04
243  RCL 12
244  SQRT
245  +
246  LBL 01
247  ABS
248  LN
249  -
250  STO 02
251  RCL 09
252  RCL 04
253  +
254  ENTER
255  X^2
256  RCL 04
257  X^2
258  -
259  RCL 12
260  +
261  SQRT
262  +
263  ABS
264  LN
265  ST- 01
266  LBL 05
267  SF 24
268  RCL 00        
269  X#0?
270  SIGN
271  X<> 00
272  ABS
273  SQRT
274  X=0?
275  SIGN
276  1/X
277  STO 04
278  ST* 05
279  ST* 06
280  RCL 10
281  ABS
282  SQRT
283  ST+ X
284  X=0?
285  SIGN
286  ST/ 01
287  ST/ 02
288  ST/ 03
289  1377 E7
290  ST* 01
291  ST* 02
292  ST* 03
293  ST* 04
294  ST* 05
295  ST* 06
296  RCL 03
297  SIGN
298  RCL 00
298  RCL 04
300  RCL 02
301  RCL 01
302  CF 24
303  END

 
           ( 368 bytes / SIZE 013 )
 
 

      STACK        INPUTS      OUTPUTS
           T             /           k
           Z           ¶0           R0
           Y        L0 < 0            t0
           X            z            D
           L            /            P

  where the distances are expressed in light-years and the times in years

Example1:    With   ¶0 = -0.0001  ,   L0 = -0.1  ,  z = 10

      -0.0001  ENTER^
         -0.1     ENTER^
           10     XEQ "TOL"   >>>>   D  = 1.2148    E10  l-y     = R01
                                          RDN    t0 =  1.3336   E10  years = R02
                                          RDN   R0 =  1.3129   E10  L-y   = R04
                                          RDN    k  =   -1                          = R00
                                       LASTX   P  =  1.3680   E11 years = R03

 And we also have:

    R05 =  Rmin =  1.2517   E08  l-y
    R06 =  Rmax =  4.3544   E10 l-y
    R07 =  zmin  =  -0.6985
    R08 =  zmax  =  103.8852

Example2:       ¶0 = 0.1  ,  L0 = 0.6  ,   z  = 7

         0.1   ENTER^
         0.6   ENTER^
           7    XEQ "TOL"  >>>>  D = 1.1670   E10   light-years
                                      RDN   t0 = 1.2006   E10   years
                                      RDN  R0 = 2.5140   E10   light-years
                                      RDN   k  = -1  ( hyperbolic Universe )
                                   LASTX  P =  9.9999   E99  ( infinte )

 We also have:

    R05 =  Rmin =  0
    R06 =  Rmax =  9.9999   E99  ( infinte )
    R07 =  zmin  = -9.9999   E99  ( infinte )
    R08 =  zmax  =  9.9999   E99  ( infinte )
 

Example2:       ¶0 = 1.1  ,  L0 = 0  ,   z  = 7

         1.1   ENTER^
          0     ENTER^
          7     XEQ "TOL"  >>>>  D = 6.6184   E09   light-years
                                      RDN   t0 = 6.7210   E09   years
                                      RDN  R0 = 4.3545   E10   light-years
                                      RDN   k  = +1  ( spherical Universe )
                                   LASTX  P =  2.8884   E11   years

 We also have:

    R05 =  Rmin =  0
    R06 =  Rmax =  1.4442   E11  light-years
    R07 =  zmin  = -0.6985
    R08 =  zmax  =  9.9999   E99  ( infinte )
 

5°)  Other Cyclic Universes without Singularity
 

-Instead of solving Einstein's equations in a homogeneous & isotropic Universe:

  2 R(t).d2R/dt2 + (dR/dt)2 + k.c2 = ( -(8.PI.G/c2 ).p + (Lambda).c2 ).R2(t)
     (dR/dt)2 + k.c2  = ( (8.PI.G/3) (rho) + (Lambda/3).c2 ).R2(t)
 

"PULSE" employs these equations to calculate different parameters for a given date,
 assuming that the radius of the Universe may be expressed as a function of time by

    R(t) = A + B Sin2 ( Pi t / P )

 A = Rmin  is the positive minimum of the scale factor and A+B = Rmax
 

-We have also    H = R' / R  ,  q = - R R" / R'2  ,  L = Lambda c2 R2 / ( 3 R'2 )   with  ' = d/dt
 

Data Registers:           •  R00 = k  ( -1 , 0 or +1 )                     ( Registers R00 thru R04 are to be initialized before executing "PULSE" )

                                      •  R01 = A = Rmin ( in light-years )                                          R05 = R                                             R09: temp
                                      •  R02 = B  ( in light-years )                                                      R06 = H ( km/s/Mpc )                        R10 = t
                                      •  R03 = P = period ( in years )                                                 R07 = q = deceleration parameter
                                      •  R04 = Lambda = Cosmological constant ( in light-years-2 )    R08 = L = Cosmological parameter
Flags: /
Subroutines: /
 
 
 
 

 01  LBL "PULSE"
 02  DEG
 03  STO 10        
 04  180
 05  *
 06  RCL 03
 07  /
 08  STO 09
 09  ST+ X
 10  SIN
 11  RCL 02
 12  *
 13  PI
 14  *
 15  RCL 03
 16  /
 17  STO 06
 18  X^2
 19  RCL 00
 20  +
 21  RCL 09
 22  SIN
 23  X^2
 24  RCL 02        
 25  *
 26  RCL 01
 27  +
 28  STO 05
 29  ST/ 06
 30  X^2
 31  /
 32  RCL 09
 33  ST+ X
 34  COS
 35  RCL 02
 36  *
 37  PI
 38  RCL 03
 39  /
 40  X^2
 41  *
 42  RCL 05        
 43  /
 44  ST+ X
 45  STO 07 
 46  ST+ X
 47  +
 48  X<>Y
 49  RCL 04
 50  ST- Z
 51  3
 52  /
 53  STO 08
 54  -
 55  16702 E2
 56  CHS
 57  ST/ Z
 58  CHS
 59  /
 60  3
 61  *
 62  RCL 06        
 63  X=0?
 64  GTO 00
 65  X^2
 66  ST/ 08
 67  CHS
 68  ST/ 07
 69  GTO 01
 70  LBL 00
 71  CLX
 72  RCL 04
 73  X#0?
 74  SIGN
 75  90
 76  TAN
 77  *
 78  STO 08
 79  X<> L
 80  RCL 07
 81  SIGN
 82  *
 83  CHS
 84  STO 07        
 85  LBL 01
 86  CLX
 87  RCL 06
 88  9778 E8
 89  *
 90  STO 06
 91  STO T
 92  CLX
 93  RCL 07
 94  SIGN
 95  CLX
 96  RCL 05
 97  END

 
         ( 134 bytes / SIZE 011 )
 
 

      STACK        INPUTS      OUTPUTS
           T             /   H ( km/s/Mpc )
           Z             /     p/c2 ( kg/m3 )
           Y             /     rho ( kg/m3 )
           X            t          R(t)
           L            /            q

  Where the distances are expressed in light-years and the times in years ( c = 1 )

                  H = Hubble's "constant" = R' / R
                   p = pressure
      and      rho = density
                   R  = scale factor
                   q  = deceleration parameter

Example:   With k = +1 ( Spherical Universe )  ,  A = Rmin = 7 108 L-y  ,  B = 84 109 L-y  ,  P = 116 109 L-y  ,  Lambda = 10 -20 L-y -2

       1       STO 00
     7 E8    STO 01
    84 E9   STO 02
   116 E9  STO 03
     E-20    STO 04

-If   t = 25 109 years    25 E9  XEQ "PULSE"  >>>>    R  = 3.367 E10  = R05
                                                                        RDN   rho =  3.417 E-27 kg/m3
                                                                        RDN   p/c2 = 1.910 E-27 kg/m3
                                                                        RDN    H   =  64.519   km/s/Mpc  = R06
                                                                      LASTX   q   =  -0.181  =  R07

   and    R08 = Cosmological parameter = L = 0.766

Notes:

-In this fictitious Universe, the mass is not constant and the pressure - even the density - may be negative
-Here are a few other values:  (  9.999...  E99 = infinity )
 
 

        t            R           rho         p/c^2          H            q            L
       0         7 E8    3.660  E-24   -1.427  E-24          0    -9.999  E99    +9.999  E99
    7 E9     3.683  E09    2.203  E-25   -1.067  E-25    223.556        -0.595         0.064
   12 E9     9.264  E09    5.461  E-26   -2.689  E-26    145.311        -0.479         0.151
   24 E9     3.146  E10    4.545  E-27   +1.222 E-27     68.121        -0.216         0.687
   58 E9     8.470  E10   -5.737 E-27   +7.646 E-27          0    +9.999  E99    +9.999  E99

 
-With the same constants in R00 thru R03 but  R04 = Lambda = 0  we find:
 
 

           t            R           rho          p/c^2            H             q    L
          0         7 E8    3.666  E-24    -1.433  E-24            0     -9.999  E99    0
       7 E9     3.683  E09    2.263  E-25    -1.127  E-25      223.556         -0.595    0
      12 E9     9.264  E09    6.060  E-26    -3.288  E-26      145.311         -0.479    0
      24 E9     3.146  E10    1.053  E-26    -4.765  E-27       68.121         -0.216    0
      41 E9     6.812  E10    1.657  E-27    +7.586 E-28       25.997         +1.549    0
      58 E9     8.470  E10    2.504  E-28    +1.659 E-27            0     +9.999  E99    0
      75 E9     6.812  E10    1.657  E-27    +7.586 E-28      -25.997         +1.549    0
      92 E9     3.146  E10    1.053  E-26    -4.765  E-27      -68.121         -0.216    0
     104 E9     9.264  E09    6.060  E-26    -3.288  E-26     -145.311         -0.479    0
     109 E9     3.683  E09    2.263  E-25    -1.127  E-25     -223.556         -0.595    0
     116 E9         7 E8    3.666  E-24    -1.433  E-24           0     -9.999  E99    0

 
-Here, rho is always positive.
-After t = 58 E9, the results are symmetric, with a sign change for the Hubble parameter H ( contraction after expansion )

-During the expansion, the pressure p = 0 for t = 36.1378 E9 ( approximately )
    and the deceleration parameter    q = 0 for t = 29 E9 = P / 4   ( exactly )  i-e  when R" = 0
 

Remark:

-Use the following variant if you prefer to get the density parameter and the pressure parameter ( instead of rho & p/c2 )
 
 
 

 01  LBL "PULSE"
 02  DEG
 03  STO 10        
 04  PI
 05  RCL 03
 06  /
 07  STO 07
 08  R-D
 09  *
 10  STO 09
 11  ST+ X
 12  SIN
 13  RCL 02
 14  *
 15  RCL 07
 16  *
 17  STO 06        
 18  X^2
 19  RCL 00
 20  +
 21  RCL 09
 22  SIN
 23  X^2
 24  RCL 02
 25  *
 26  RCL 01
 27  +
 28  STO 05
 29  ST/ 06
 30  X^2
 31  /
 32  RCL 09        
 33  ST+ X
 34  COS
 35  RCL 02
 36  RCL 07
 37  X^2
 38  *
 39  *
 40  RCL 05
 41  /
 42  ST+ X
 43  STO 07
 44  ST+ X
 45  +
 46  X<>Y
 47  RCL 04        
 48  ST- Z
 49  3
 50  /
 51  STO 08
 52  -
 53  RCL 06
 54  X=0?
 55  GTO 00
 56  X^2
 57  ST/ 08
 58  ST/ Y
 59  CHS
 60  ST/ 07
 61  ST/ Z
 62  GTO 01
 63  LBL 00
 64  90
 65  TAN
 66  STO 08        
 67  R^
 68  CHS
 69  SIGN
 70  *
 71  R^
 72  SIGN
 73  RCL 08
 74  ST* Y
 75  RCL 07
 76  SIGN
 77  *
 78  CHS
 79  STO 07        
 80  CLX
 81  RCL 04
 82  X#0?
 83  SIGN
 84  ST* 08
 85  LBL 01
 86  CLX
 87  RCL 06
 88  9778 E8
 89  *
 90  STO 06        
 91  STO T
 92  CLX
 93  RCL 07
 94  SIGN
 95  CLX
 96  RCL 05
 97  END

 
        ( 128 bytes / SIZE 011 )
 
 

      STACK        INPUTS      OUTPUTS
           T             /   H ( km/s/Mpc )
           Z             /            ¶
           Y             /       OmegaMat
           X             t          R(t)
           L             /            q

  Where the distances are expressed in light-years and the times in years ( c = 1 )

                  H        = Hubble's "constant" = R' / R
                  ¶         = pressure parameter = 8 PI G p / ( c2 H2 )
  and    OmegaMat = density parameter = 8 PI G rho / ( 3 H2 )
                 R         = scale factor
                 q         = deceleration parameter = - R R" / R'2

Example:   With k = +1 ( Spherical Universe )  ,  A = Rmin = 108 L-y  ,  B = 84 109 L-y  ,  P = 173 109 L-y  ,  Lambda = 10 -20 L-y -2

       1       STO 00
     1 E8    STO 01
    84 E9   STO 02
   173 E9  STO 03
     E-20    STO 04

-If   t = 25 109 years    25 E9  XEQ "PULSE"  >>>>          R         =  16.256 E9  = R05                       ---Execution time = 4s---
                                                                        RDN   Omega(mat) =  1.082
                                                                        RDN          ¶           = -0.631
                                                                        RDN          H          =  72.327   km/s/Mpc  = R06
                                                                      LASTX         q         =  -0.383  =  R07

   and    R08 = Cosmological parameter = L = 0.609
 

>>> The last 2 versions may be put together if we use a flag ( for instance F01 ):
 

Data Registers:           •  R00 = k  ( -1 , 0 or +1 )                     ( Registers R00 thru R04 are to be initialized before executing "PULSE" )

                                      •  R01 = A = Rmin ( in light-years )                                          R05 = R                                             R09: temp
                                      •  R02 = B  ( in light-years )                                                      R06 = H ( km/s/Mpc )                        R10 = t
                                      •  R03 = P = period ( in years )                                                 R07 = q = deceleration parameter
                                      •  R04 = Lambda = Cosmological constant ( in light-years-2 )    R08 = L = Cosmological parameter

Flag:  F01           CF 01 ->  Y-Z outputs = OmegaMat  &   ¶
                            SF 01  ->  Y-Z outputs =  rho & p / c2
Subroutines: /
 
 

 01  LBL "PULSE"
 02  DEG
 03  STO 10         
 04  PI
 05  RCL 03
 06  /
 07  STO 07
 08  R-D
 09  *
 10  STO 09
 11  ST+ X
 12  SIN
 13  RCL 02
 14  *
 15  RCL 07
 16  *
 17  STO 06
 18  X^2
 19  RCL 00         
 20  +
 21  RCL 09
 22  SIN
 23  X^2
 24  RCL 02
 25  *
 26  RCL 01
 27  +
 28  STO 05
 29  ST/ 06
 30  X^2
 31  /
 32  RCL 09
 33  ST+ X
 34  COS
 35  RCL 02         
 36  RCL 07
 37  X^2
 38  *
 39  *
 40  RCL 05
 41  /
 42  ST+ X
 43  STO 07
 44  ST+ X
 45  +
 46  CHS
 47  X<>Y
 48  RCL 04
 49  ST+ Z
 50  3
 51  /
 52  STO 08         
 53  -
 54  FC? 01
 55  GTO 00
 56  16702 E2
 57  ST/ Z
 58  /
 59  3
 60  *
 61  LBL 00
 62  RCL 06
 63  X=0?
 64  GTO 00
 65  X^2
 66  ST/ 08
 67  FC? 01
 68  ST/ Y
 69  FC? 01
 70  ST/ Z
 71  CHS
 72  ST/ 07
 73  GTO 01
 74  LBL 00
 75  CLX
 76  90
 77  TAN
 78  STO 08         
 79  FS? 01
 80  GTO 00
 81  ENTER
 82  R^
 83  SIGN
 84  *
 85  R^
 86  SIGN
 87  RCL 08         
 88  ST* Y
 89  LBL 00
 90  RCL 07
 91  SIGN
 92  *
 93  CHS
 94  STO 07
 95  CLX
 96  RCL 04
 97  X#0?
 98  SIGN
 99  ST* 08
100  LBL 01
101  CLX
102  RCL 06         
103  9778 E8
104  *
105  STO 06
106  STO T
107  CLX
108  RCL 07
109  SIGN
110  CLX
111  RCL 05
112  END

 
         ( 156 bytes / SIZE 011 )
 
 

      STACK        INPUTS      OUTPUTS
           T             /   H ( km/s/Mpc )
           Z             /     ¶  or  p/c^2
           Y             /  OmMat or rho
           X             t          R(t)
           L             /            q

  Where the distances are expressed in light-years and the times in years ( c = 1 )

                  H        = Hubble's "constant" = R' / R
                  ¶         = pressure parameter = 8 PI G p / ( c2 H2 )
  and    OmegaMat = density parameter = 8 PI G rho / ( 3 H2 )
                 R         = scale factor
                 q         = deceleration parameter = - R R" / R'2

Example:   With k = +1 ( Spherical Universe )  ,  A = Rmin = 108 L-y  ,  B = 84 109 L-y  ,  P = 173 109 L-y  ,  Lambda = 10 -20 L-y -2

       1       STO 00
     1 E8    STO 01
    84 E9   STO 02                and   t = 25 109 years
   173 E9  STO 03
     E-20    STO 04

  •  CF 01

     25 E9  XEQ "PULSE"  >>>>          R         =  16.256 E9  = R05                       ---Execution time = 4s---
                                          RDN   Omega(mat) =  1.082
                                          RDN          ¶           = -0.631
                                          RDN          H          =  72.327   km/s/Mpc  = R06
                                       LASTX         q           =  -0.383  =  R07

   and    R08 = Cosmological parameter = L = 0.609

  •  SF 01

     25 E9    R/S     >>>>    R  =  16.256 E9  = R05                       ---Execution time = 4s---
                             RDN   rho =  1.064  E-26 kg/m3
                             RDN   p/c2 = -2.066  E-27 kg/m3
                             RDN     H  =  72.327   km/s/Mpc  = R06
                          LASTX     q  =  -0.383  =  R07

   and    R08 = Cosmological parameter = L = 0.609
 

Note:

-Though the real Universe is probably different from these models - but who knows ? -
  you can use these programs to explore various pulsing Universes to get a better fit...
 
 

References:

[1]  Stamatia Mavridès - "L'Univers relativiste" - Masson  ISBN 2-225-36080-7  ( in French )
[2]  Jean Heidmann - "Introduction à la cosmologie" - PUF  ( in French )
[3]  David F. Crawford - "Curvature Cosmology" - ISBN 1-59942-413-4
      or http://www.davidcrawford.bigpondhosting.com/cc2.pdf
[4]  J. Pachner - "An Oscillating Isotropic Universe without Singularity" - Mon. Not. R. astr. Soc. ( 1965 ) 131, 173-176
[5]  Hua-Hui Xiong, Yi-Fu Cai, Taotao Qiu, Yun-Song Piao, Xinmin Zhang - "Oscillating universe with quintom matter"