hp41programs

Solar System Barycenter

Barycenter of the Solar System for the HP-41


Overview
 

-This program calculates the rectangular heliocentric ecliptic coordinates X , Y of the center of mass of the Solar system ( we make the approximation Z = 0 )
-It takes a date YYYY.MNDD and returns the distance G between the Solar system barycenter B and the center of the Sun S.

-Only the 4 giant planets are taken into account: the other planets have a negligible effect.
-The positions of these planets are not computed very accurately: the terms in e2 are neglected ( e = eccentricity ),
  and only one term in the perturbations is taken into account.
 

Data Registers:   R00 = T in millennia since 2000/01/01 0h TT

                              R01 = X
                              R02 = Y        R03 to R11: temp
Flags: /
Subroutine:    "J0"  ( cf "Julian & Gregorian Calendars" )  or  "J1"  or  "J2"

-Line 12 may be replaced by  20
 
 

  01  LBL "BOSS"
  02  DEG
  03  XEQ "J0"
  04  365250
  05  /
  06  STO 00
  07  CLX
  08  STO 01
  09  STO 02
  10  12.4
  11  STO 03
  12  19.98
  13  STO 04
  14  20.6
  15  STO 05
  16  10
  17  STO 06
  18  16.13
  19  STO 07
  20  14.33
  21  STO 08
  22  1.066
  23  STO 09
  24  178
  25  RCL 00
  26  407
  27  *
  28  -
  29  STO 10		   30  .32
  31  CHS
  32  STO 11        
  33  30346.9
  34  XEQ 01
  35  31
  36  STO 03
  37  43
  38  CHS
  39  STO 04
  40  18
  41  STO 05
  42  12
  43  STO 06
  44  19.64
  45  STO 07
  46  93.06
  47  STO 08
  48  .586
  49  STO 09
  50  .8
  51  STO 11
  52  12215.47
  53  XEQ 01
  54  111
  55  CHS
  56  STO 03
  57  141.04
  58  STO 04		   59  21.6
  60  STO 05
  61  47
  62  STO 06        
  63  14.86
  64  STO 07
  65  173
  66  STO 08
  67  .18
  68  STO 09
  69  65
  70  RCL 00
  71  85
  72  *
  73  -
  74  STO 10
  75  .86
  76  CHS
  77  STO 11
  78  4283.78
  79  XEQ 01
  80  143
  81  STO 03
  82  256.22
  83  STO 04
  84  111
  85  STO 05
  86  27
  87  STO 06		   88  14.26
  89  STO 07
  90  48.12
  91  STO 08        
  92  .335
  93  STO 09
  94  .58
  95  STO 11
  96  2184.57
  97  LBL 01
  98  RCL 00
  99  RCL 03
100  /
101  -
102  RCL 00
103  *
104  RCL 04
105  +
106  ENTER^
107  SIN
108  RCL 05
109  /
110  ST+ X
111  R-D
112  RCL 00
113  RCL 06
114  /
115  RCL 07
116  +		 117  RCL 00
118  *
119  RCL 08        
120  +
121  +
122  +
123  RCL 10
124  SIN
125  RCL 11
126  *
127  +
128  1
129  R^
130  COS
131  RCL 05
132  /
133  -
134  RCL 09
135  *
136  P-R
137  ST+ 01
138  X<>Y
139  ST+ 02
140  RCL 02
141  RCL 01
142  R-P
143  END

 
   ( 285 bytes / SIZE 012 )
 
 

      STACK        INPUTS      OUTPUTS
           Y             /             µ
           X  YYYY.MNDD             G

   where   G = distance Barycenter-Center of the Sun  ( unit = solar radius )
     and     µ  = ( Sx , SB )

Example:

   2008.0824   XEQ "BOSS"    >>>>    G =     1.0761                    ---Execution time = 27s---
                                                X<>Y    µ =  -74°0782

  Since G > 1 , the Solar system barycenter is currently outside the Sun's globe.
  G will be smaller than one in April 2010

  We have also

     X = R01 =  0.2952
     Y = R02 = -1.0348

Other Checkings:

  on  1983/03/15    G = 2.098   ( exact result - almost the maximum possible value )
  on  1990/04/23    G = 0.069   ( exact value = 0.066 )
  on  2130/03/10    G = 0.016   ( exact value = 0.021 )

Note:

  Errors seem smaller than 0.01 over the time span [ 1000 , 3000 ]
  µ may be inaccurate if G is very small
 

Reference:

 [1]  Jean Meeus - "Mathematical Astronomy Morsels" - Willmann-Bell  -  ISBN 0-943396-51-4