hp41programs

Biorhythms

Biorhythms for the HP-41


Overview
 

 1°)  7 Biorhythms
 2°)  Planetary Biorhythms
 
 

1°)  7 Biorhythms
 

-This program displays 7 biorhythms: physical, emotional, intellectual, intuitive, esthetic, self-awareness, spiritual.
-It uses 7 cycles: 23  28  33  38  43  48  53 days respectively.
 
 

Data Registers:     R00: temp             R08 = age expressed in days      R09 = day of birth     R10 = time of birth

                                R01: physical         R03: intellectual     R05: esthetic               R07: spiritual
                                R02: emotional      R04: intuitive          R06: self-awareness

Flag:  F22
Subroutines: /
 
 
 

 01 LBL "BIO"
 02 "DOBIRTH^TIME"
 03 CF 22
 04 PROMPT 
 05 FC?C 22
 06 GTO 00
 07 STO 10                  
 08 X<>Y
 09 STO 09
 10 LBL 00
 11 7
 12 STO 00
 13 53
 14 STO 07
 15 48
 16 STO 06		  17 43
 18 STO 05
 19 38
 20 STO 04  
 21 33
 22 STO 03 
 23 28
 24 STO 02                  
 25 23
 26 STO 01
 27 RCL 09
 28 DATE
 29 DDAYS
 30 TIME
 31 RCL 10
 32 HMS-		  33 HR
 34 24
 35 /
 36 +
 37 STO 08 
 38 DEG
 39 LBL 14
 40 RCL 08                  
 41 360
 42 *
 43 RCL IND 00
 44 /
 45 SIN
 46  E2
 47 *
 48 STO IND 00		  49 DSE 00
 50 GTO 14
 51 1.007
 52 STO 00                  
 53 CLX
 54 "  "
 55 FIX 0
 56 CF 29
 57 LBL 11
 58 RCL IND 00
 59 ST+ Y
 60 X<0?
 61 FS? 30
 62 >"+"
 63 X<0?
 64 >"-"		  65 RND
 66 ABS
 67 10
 68 X>Y?
 69 >"0"
 70 RDN
 71 ARCL X
 72 RDN
 73 ISG 00
 74 GTO 11
 75 7
 76 /
 77 RCL 08                 
 78 X<>Y
 79 FIX 04
 80 AVIEW
 81 END

 
      ( 144 bytes / SIZE 011 )
 
 

        STACK          INPUTS       OUTPUTS
            Y               /    age ( in days )
            X               /   average biorhythm

 
Example:    Assuming you were born on  07/07/1984  at  16h41m   and  lines 28-30  are executed on 01/01/2019  at  23h45m

    XEQ "BIO"    >>>>    "DOBIRTH^TIME"

      7.071984     ENTER^
         16.41            R/S           >>>>      -86-74-96+12-39+47-86

-So   physical       = -86%
        emotional     = -74%
        intellectual    = -96%
          intuitive      = +12%
          esthetic      = -39%
    self-awareness = +47%
         spiritual       = -86%

-Press the backarrow key:       X = -46.1091 % = average biorhythm        X<>Y      your age = 12596.2944  days
 

Notes:

-The date must be expressed in the current format  ( DMY or MDY )
-Press R/S without any digit entry if the day & time of birth are already stored in R09 & R10.
-If you always use the same day & time of birth, replace lines 28 & 30 by these values and delete lines 02 to 10

-If you don't have a TIME module, you can use a subroutine like "J0" ( cf "Julian & Gregorian Calendars for the HP41" )
-In this case, the time of birth is not taken into account.

-The results are still in the alpha "register" when the program stops.
-And with a better precision in R01 thru R07
 

2°)  Planetary Biorhythms
 

-"BIOPL" calculates the cosines of the differences between the heliocentric longitudes of the planets ( and the Moon ) and the heliocentric longitude of the Earth.
-The precision is very low...
 
 
 

Data Registers:   R00 = Time in century since 2000/01/01 0h TT            R10 & R11: temp

                              R01 = Mercury longitude           R04 = Mars longitude             R07 = Uranus longitude
                              R02 = Venus longitude              R05 = Jupiter longitude            R08 = Neptune longitude
                              R03 = Earth longitude                R06 = Saturn longitude            R09 = Moon longitude

Flag:  F10 is cleared
Subroutines: /
 
 
 
 

 01 LBL "BIOPL"
 02 DEG
 03 HR
 04 24
 05 /
 06 X<>Y
 07 1.012
 08 DDAYS
 09 -
 10 36525
 11 /
 12 STO 00         
 13 1494741
 14 *
 15 2502
 16 +
 17 RCL 00
 18 16
 19 *
 20 775
 21 +
 22 206
 23 SF 10
 24 XEQ 10
 25 STO 01
 26 RCL 00
 27 585192
 28 *
 29 1812
 30 +
 31 RCL 00
 32 14
 33 *
 34 1316
 35 +
 36 7
 37 XEQ 10
 38 STO 02		  39 RCL 00
 40 360008
 41 *
 42  E3
 43 +
 44 RCL 00         
 45 17
 46 *
 47 1029
 48 +
 49 17
 50 XEQ 10
 51 STO 09
 52 RCL 00
 53 191417
 54 *
 55 48
 56 -
 57 RCL 00
 58 18
 59 *
 60 239
 61 -
 62 93
 63 XEQ 10
 64 STO 04
 65 RCL 00
 66 30363
 67 *
 68 343
 69 +
 70 RCL 00
 71 16
 72 *
 73 143
 74 +
 75 48
 76 XEQ 10		  77 STO 05
 78 RCL 00
 79 12235
 80 *
 81 501
 82 +
 83 RCL 00         
 84 20
 85 *
 86 931
 87 +
 88 56
 89 XEQ 10
 90 STO 06
 91 RCL 00
 92 4299
 93 *
 94 460
 95 -
 96 RCL 00
 97 149
 98 *
 99 1730
100 +
101 46
102 XEQ 10
103 STO 07
104 RCL 00
105 2198
106 *
107 557
108 -
109 RCL 00
110 14
111 *
112 481
113 +
114 9		 115 CF 10
116 LBL 10
117  E3
118 /
119 STO 11
120 CLX
121 10
122 ST/ Z
123 /
124 STO 10        
125 -
126 1
127 P-R
128 RCL 11
129 -
130 R-P
131 CLX
132 2
133 /
134 1
135 RCL 11
136 +
137 1
138 LASTX
139 -
140 /
141 SQRT
142 P-R
143 LASTX
144 /
145 R-P
146 X<>Y
147 ST+ X
148 RCL 10
149 +
150 360
151 MOD
152 FS? 10		 153 RTN
154 STO 08
155 RCL 00
156 481267.9
157 *
158 211.7
159 +
160 RCL 00        
161 477199
162 *
163 128
164 +
165 STO 10
166 SIN
167 PI
168 ST+ X
169 *
170 +
171 890534
172 RCL 00
173 *
174 236
175 +
176 STO 11
177 RCL 10
178 -
179 SIN
180 1.3
181 *
182 +
183 RCL 11
184 SIN
185 .7
186 *
187 +
188 360
189 MOD
190 STO 03		 191 RCL 00
192 39
193 *
194 STO 10        
195 83
196 +
197 COS
198 3
199 /
200 ST+ 05
201 RCL 10
202 97
203 -
204 COS
205 .8
206 *
207 ST+ 06
208 RCL 00
209 8
210 *
211 STO 10
212 152
213 -
214 COS
215 .9
216 *
217 ST+ 07
218 RCL 10
219 28
220 +
221 COS
222 .6
223 *
224 ST+ 08
225 1.008
226 STO 10
227 FIX 00
228 CF 29		 229 CLA
230 CLX
231 LBL 14
232 RCL IND 10
233 RCL 09        
234 -
235 COS
236 X<0?
237 FS? 30
238 >"+"
239 X<0?
240 >"-"
241  E2
242 *
243 ST+ Y
244 RND
245 ABS
246 10
247 X>Y?
248 >"0"
249 X^2
250 X=Y?
251 >"E2"
252 X#Y?
253 ARCL Y
254 R^
255 R^
256 ISG 10
257 GTO 14
258 8
259 /
260 RCL 03
261 X<> 09
262 STO 03
263 X<>Y
264 FIX 04
265 SF 29
266 AVIEW
267 END

 
         ( 466 bytes / SIZE 012 )
 
 

        STACK          INPUTS       OUTPUTS
            Y             Date             LE
            X           hh.mnss    average rhythm

   where Date must be expressed in the current format ( MDY or DMY )
     and     LE = heliocentric longitude of the Earth in decimal degree.

Example:    On  01/01/2019  at  23h45m

     1.012019  ENTER^
         23.45    XEQ "BIOPL"   >>>>   -24.1129 ( % )

  and the HP41 displays the alpha "register"    -61+76-69+51-82-E2+35-43    meaning:

    Mercury   -61%          Mars     +51%           Uranus   +35%
    Venus      +76%          Jupiter   -82%           Neptune  -43%
    Moon       -69%          Saturn  -100%

-And we find the heliocentric longitudes in R01 thru R09:

    Mercury     228°63           Mars       42°21          Uranus      31°68
    Venus        141°97           Jupiter    246°85          Neptune  345°67
    Earth          101°31           Saturn    281°66          Moon      234°61
 

Notes:

-During the execution of the program, R03 = longitude of the Moon
-Lines 260 to 262 exchanges R03 & R09

-Since the alpha register can only contain 24 characters, 100 is displayed E2

-The heiocentric longitudes are referred to the mean ecliptic of the date
-In the example above, the correct values are:

    Mercury     228°58           Mars       42°24          Uranus      31°32
    Venus        141°91           Jupiter    246°83          Neptune  345°78
    Earth          101°27           Saturn    281°53          Moon      235°11

-Of course, this program was just written for the fun...