Great Planetary Conjunctions for the HP-41

Overview
 

-This program tests successive New Moons to find great planetary conjunctions - geocentric positions.
-You give an initial date and an angle A to your HP-41 and your calculator
  will return the date of the next ( approximate ) conjunction and the angle µ as shown below ( µ <= A )

-Pluto is not taken into account.
 

                                                                               /  *
                                                                             /                         *
                                                                           /  µ                 *                  Planets
                       Earth ------ Moon ------------Sun -------------------------
                                                                          \  µ                                      *
                                                                            \         *
                                                                              \                             *
 

-The orbits are supposed circular (!) , so it is only a rough approximation...
-Check the results with a good software like "SOLEX" ( reference [1] )

-Of course, an emulator like V41 in turbo mode is almost indispensable.
 

Program Listing
 
 

Data Registers:   R00 thru R20: temp
Flags: /
Subroutines:  "J2" & "D2" ( cf "Julian and Gregorian Calendars for the HP-41" )

-Line 148 is a three-byte GTO 00
 
 

01  LBL "GPC"   02  XEQ "J2"   03  29.53058886    04  STO 20    05  /   06  INT   07  STO 16   08  X<>Y    09  STO 17   10  28.216   11  STO 01             12  1134733.024   13  STO 02   14  98.487   15  STO 03   16  225184.432   17  STO 04   18  74.968   19  STO 05   20  168590.733   21  STO 06   22  113.885   23  STO 07   24  329644.67   25  STO 08   26  129.611   27  STO 09   28  347772.588   29  STO 10   30  .022   31  STO 11   32  33.584   33  STO 12   34  355709.054

35  STO 13   36  23.883   37  STO 14    38  357808.869   39  STO 15    40  12368.53   41  STO 18   42  GTO 01   43  LBL 00   44  RCL 00             45  73 E-7   46  *   47  15 E-5   48  -   49  RCL 00   50  *   51  .015437    52  +   53  RCL 00   54  X^2   55  *   56  5.59766   57  +   58  RCL 16   59  RCL 20   60  *   61  +   62  INT   63  LASTX   64  FRC   65  X<0?   66  DSE Y   67  FRC   68  24

69  ST* Y   70  MOD   71  HMS    72  X<>Y   73  XEQ "D2"   74  RCL 19             75  X<> Z   76  X<>Y   77  CLD    78  RTN   79  LBL 10   80  ISG 16   81  LBL 01   82  CLX   83  X<> 19   84  VIEW 16   85  RCL 16   86  RCL 18   87  /   88  STO 00   89  RCL 02   90  *   91  RCL 01   92  -   93  XEQ 02   94  X>Y?   95  GTO 10   96  RCL 04   97  RCL 00   98  *   99  RCL 03 100  - 101  XEQ 02 102  X>Y?

103  GTO 10 104  RCL 05 105  RCL 06 106  RCL 00           107  * 108  - 109  XEQ 02 110  X>Y? 111  GTO 10 112  RCL 07 113  RCL 08 114  RCL 00 115  * 116  - 117  XEQ 02 118  X>Y? 119  GTO 10 120  RCL 11 121  RCL 00 122  * 123  RCL 10 124  - 125  RCL 00 126  * 127  RCL 09 128  + 129  XEQ 02 130  X>Y? 131  GTO 10 132  RCL 12 133  RCL 13 134  RCL 00 135  * 136  -

137  XEQ 02 138  X>Y? 139  GTO 10 140  RCL 14           141  RCL 15 142  RCL 00 143  * 144  - 145  XEQ 02 146  X>Y? 147  GTO 10 148  GTO 00 149  LBL 02 150  360 151  MOD 152  PI 153  R-D 154  X>Y? 155  CLX 156  ST+ X 157  - 158  ABS 159  ABS 160  RCL 19 161  X<Y? 162  X<>Y 163  STO 19 164  RCL 17 165  LASTX 166  RTN 167  END

 
     ( 367 bytes / SIZE 021 )
 
 

STACK	INPUTS	OUTPUTS
Z	/	µ
Y	A	HH.MNSS
X	yyyy.mndd	YYYY.MNDD

  Where the angles A and µ are expressed in degrees and the dates in the Gregorian Calendar.

Example:   Let's start with A = 60° and yyyy.mndd = 2000.0101

        60         ENTER^
 2000.0101   XEQ "GPC"   >>>>  2203.0610
                                           RDN       13.2613
                                           RDN        54.1°

-For the next conjuction, simply press  R/S  >>>>   2673.0408
                                                                   RDN        19.3755
                                                                   RDN        56.4°                  ... and so on ...

-Let's check these results with SOLEX

    •  On 2203/06/10 at 13h26m13s  we find the following geocentric ecliptic longitudes

   Sun      L = 78°9
  Moon   L = 77°7
Mercury  L = 95°9
 Venus     L = 74°8
  Mars     L = 71°6              So, all these celestial bodies are inside an angular sector of 68°4  Not perfect but better than 2x54°1
 Jupiter    L = 93°5
 Saturn    L = 18°9
 Uranus   L = 101°6
Neptune  L = 33°2

    •  On 2673/04/08 at 19h37m55s  we find the following geocentric ecliptic longitudes

   Sun      L = 19°3
  Moon   L = 12°4
Mercury  L = 17°3
 Venus     L = -3°1
  Mars     L =  0°9               Now, an angular sector of 58°6  Not perfect but again better than 2x56°4 ... and even better than the first example
 Jupiter    L = -39°3
 Saturn    L =  2°6
 Uranus   L = -26°9
Neptune  L = -15°2

Notes:

-The numbers of the successive New Moons are displayed when the program is running
-N°0 = New Moon on 2000/01/06 and so on ...

-You can also seek conjunctions before a given date
-Simply replace line 80 by  DSE 16 and you'll get for instance:

        60         ENTER^
 2000.0101   XEQ "GPC"   >>>>  1664.1217
                                           RDN       20.0827
                                           RDN        54.9°

-SOLEX gives for this date:

   Sun      L = 266°7
  Moon   L = 270°6
Mercury  L = 257°3
 Venus     L = 291°1
  Mars     L = 286°4               Now, in an angular sector of 56°3  Not yet perfect but better than the first 2 examples
 Jupiter    L = 292°2
 Saturn    L = 269°8
 Uranus   L = 313°6
Neptune  L = 286°7

Notes:

-As you can see, the true angular sector is often much smaller than twice the angle A
-So, it's not really necessary to use a small A-value.

Onset of the old Hindu calendars:

-The onset of these calendars is on -3101/01/23 ( proleptic Gregorian calendar )
-It's supposed to be a conjunction of all planets + Sun + Moon.
-Let's check it !

         60         ENTER^
 -3101.0201   XEQ "GPC"   >>>>  -3101.0123
                                             RDN         4.0907
                                             RDN       51.6°

-SOLEX gives the following longitudes:

   Sun      L = 304°0
  Moon   L = 306°8
Mercury  L = 288°7
 Venus     L = 316°6
  Mars     L = 300°6
 Jupiter    L = 317°5
 Saturn    L = 276°5
 Uranus   L = 340°7
Neptune  L = 250°3
  Pluto     L = 305°7
  Eris       L = 290°6

-All these celestial bodies are in an angular sector of 90°4 - almost a quadrant.
-It is remarkable, all the more that Uranus, Neptune and - a fortiori - Pluto & Xena/Lillah/Eris were unknown at that time !
-Just a coincidence ?  Perhaps...

-The angular sector is only 40°1 if we forget the planets beyond Saturn.

Another Interesting Result:

 •  On  -5724/12/14 - Gregorian calendar - 5h38  ( "GPC" gives  µ = 34°6 )  and  SOLEX

   Sun      L = 264°5
  Moon   L = 260°8
Mercury  L = 269°6
 Venus     L = 257°9
  Mars     L = 244°6                                angular sector of  33°5
 Jupiter    L = 265°9
 Saturn    L = 236°1
 Uranus   L = 239°2
Neptune  L = 244°4

-I have not found a smaller sector !
 

References:

[1]  Aldo Vitagliano: "SOLEX" software which may be downloaded freely from http://chemistry.unina.it/~alvitagl/solex/
[2]  Jean Meeus - "Mathematical Astronomy Morsels" - Willmann-Bell  -  ISBN 0-943396-51-4

-In reference [1], Jean Meeus has investigated when planetary quadrants occur
-He calculates the heliocentric coordinates - the position of the Moon is not taken into account,
 and gives his results between the years 0 and 4000