Barycentric Dynamical Time for the HP-41
Overview
1°) Simplified Formula
2°) INPOP10
3°) Barycentric Coordinate Time
-Several time scales are available in astronomical work:
-The Terrestrial Time = TT which is related to the International
Atomic Time TAI by TT = TAI + 32.184 seconds.
-The Barycentric Dynamical Time = TDB = Temps Dynamique Barycentrique
which is preferable for the motions of planets in the Solar system.
-Due to relativistic effects, there is a difference between TDB &
TT that the following programs evaluate.
-This difference remains small: less than 2 milliseconds, at least
several millennia around J2000.
1°) Simplified Formula
-Reference [1] gives a very simple formula:
TDB - TT = 0.001658 sin M + 0.000014 sin 2M where M is the Sun's mean anomaly.
-But the program hereunder employs the first terms of the series given
in reference [2] or [3],
those whose amplitude > 0.4 second over the time-span
[1000,3000]
-The errors should not exceed 1 or 2 microseconds over this interval
of time.
Data Registers: R00 thru R03: temp
( R00 = number of millennia since 2000/01/01 12h )
Flags: /
Subroutine:
"J0" or "J1" or J2" ( cf "Julian & Gregorian Calendars for the
HP-41" )
| 01 LBL "TDB"
02 DEG 03 HR 04 24 05 / 06 X<>Y 07 XEQ "J0" 08 + 09 365250 10 / 11 STO 00 12 359993.729 13 * 14 STO 01 15 151 16 + 17 SIN 18 43 19 * 20 RCL 00 21 * 22 RCL 01 23 ST+ X 24 60 25 + 26 SIN 27 17 |
28 *
29 - 30 RCL 01 31 63 32 + 33 SIN 34 1022 35 * 36 - 37 RCL 00 38 ST* Y 39 585178 40 * 41 STO 02 42 ST+ X 43 RCL 01 44 3 45 * 46 - 47 27 48 - 49 SIN 50 6 51 * 52 - 53 RCL 01 54 ST- 02 |
55 RCL 00
56 30349 57 * 58 STO 03 59 - 60 ST+ X 61 48 62 - 63 SIN 64 8 65 * 66 - 67 RCL 02 68 9 69 - 70 COS 71 11 72 * 73 + 74 RCL 01 75 RCL 03 76 ST+ X 77 - 78 29 79 + 80 SIN 81 12 |
82 *
83 - 84 RCL 02 85 ST+ X 86 17 87 - 88 SIN 89 13 90 * 91 + 92 RCL 00 93 4452671 94 * 95 68 96 - 97 SIN 98 16 99 * 100 + 101 RCL 00 102 202 103 * 104 72 105 + 106 SIN 107 17 108 * |
109 -
110 RCL 00 111 12221 112 * 113 STO 02 114 42 115 - 116 SIN 117 23 118 * 119 + 120 RCL 01 121 RCL 02 122 - 123 50 124 + 125 SIN 126 47 127 * 128 - 129 RCL 03 130 25 131 + 132 SIN 133 48 134 * 135 + |
136 RCL 01
137 ST+ X 138 6 139 - 140 SIN 141 138 142 * 143 + 144 RCL 01 145 RCL 03 146 - 147 65.7 148 + 149 SIN 150 224 151 * 152 - 153 RCL 01 154 2.964 155 - 156 SIN 157 16567 158 * 159 + 160 E7 161 / 162 END |
( 259 bytes / SIZE 004 )
| STACK | INPUTS | OUTPUTS |
| Y | YYYY.MNDD | / |
| X | HH.MNSS | TDB-TT (s) |
Example1: 2012/08/29
16h41m37s ( TT or TDB )
2012.0829 ENTER^
16.4137
XEQ "TDB" >>>> TDB-TT = - 0.0013227 s
---Execution time =18s---
Example2: 3000/04/04 1h23m45s ( TT or TDB )
3000.0404 ENTER^
1.2345
R/S >>>> TDB-TT
= + 0.0015386 s
Note:
-In reference [1], the inputs should be expressed in TDB whereas in
refence [2], they should be expressed in TT.
-To the level of accuracy of this simplified formula, the difference
is negligible.
2°) INPOP10
-Like the JPL ephemerides DE4xx, the French ephemerides INPOP ( Integrations
Numériques Planétaires de l'Observatoire de Paris )
give the positions and velocities of the bodies of the Solar
System under the form of Chebyshev Polynomials.
-But instead of the nutation, the difference TT-TDB is also provided:
12 coefficients for each time-span of 4 days, cf reference [4]
Data Registers: • R00 = bbb.eee ( Registers R00 & Rbb thru Ree are to be initialized before executing "TDB2" )
• Rbb = JD1 • Rbb+1 = JD2
• Rbb+2 = a0 • Rbb+3 = a1
............................... • Ree = an
Flags: /
Subroutines:
"J0" or "J1" or J2" ( cf "Julian & Gregorian Calendars for the
HP-41" )
"CdT" ( cf "Orthogonal Polynomials §5-b) or "Ephemerides and
Chebyshev Polynomials for the HP-41" )
| 01 LBL "TDB2"
02 HR 03 24 04 / 05 X<>Y 06 XEQ "J0" 07 2451544.5 08 + 09 RCL IND 00 10 - 11 ST+ Y 12 ISG 00 13 CLX 14 RCL IND 00 15 LASTX 16 - 17 2 18 / 19 / 20 RCL 00 21 X<>Y 22 1 23 ST+ Z 24 ST- 00 25 - 26 XEQ "CdT" 27 CHS 28 END |
( 59 bytes / SIZE ??? )
| STACK | INPUTS | OUTPUTS |
| Y | YYYY.MNDD | / |
| X | HH.MNSS | TDB-TT (s) |
Example: 3000/04/04
1h23m45s
-In reference [4], we find a text file that contains the following constants:
2816877.00
1st Julian Date = 3000/03/31 12h TDB
2816881.00
2nd Julian Date = 3000/04/04 12h TDB
-0.15254574201273665E-02
-0.17329122056166975E-04
+0.52937767551143974E-06
+0.27550591219803854E-08
-0.34148361610150929E-09
-0.69921867908556206E-11
+0.85016053321457848E-12
+0.21451895272947141E-14
-0.14234824035252474E-14
+0.17399035530231268E-15
-0.19832610480477758E-17
-0.14385810488591148E-17
-After storing these 14 coefficients in, say R01 to R14 ( control number = 1.014 )
1.014 STO 00
3000.0404 ENTER^
1.2345
XEQ "TDB2" >>>> TDB-TT = + 0.001538845852
s
Notes:
-The argument of the INPOP ephemeris is TDB ( you can also choose TCB
), so if the input time is expressed in TT,
we must execute "TDB2" again with Time = 1h32m45s + (TDB-TT)
above to get the correct result
-In this example, it yields TDB-TT = + 0.001538845852
s
-Here, the result is unchanged and it will be almost always the same
because the HP-41 works with 10 digits.
-Anyway, one iteration is always sufficient.
3°) Barycentric Coordinate Time
-Anothe time scale may also be used: TCB = Temps Coordonné
Barycentrique = Barycentric Coordinate Time.
-Whereas TDB - TT remains smaller than 0.002 second
at least several millenia aroud J2000, the difference TCB - TDB
is much larger:
-It was almost 0 in 1977 but in 2012 , TCB -TDB is about 17 seconds.
Formula:
TCB = TDB + 1.550519768 E-8 ( JDTCB - 2443144.5003725 ) 86400 + 6.55 E-5 seconds
where JDTCB is the Julian Date in the TCB scale.
-The program below uses an iteration to compute TCB - TDB
for a given date expressed in TDB
Data Registers: R00-R01: temp
Flags: /
Subroutine:
"J0" or "J1" or J2" ( cf "Julian & Gregorian Calendars for the
HP-41" )
| 01 LBL "TCB"
02 HR 03 24 04 / 05 X<>Y 06 XEQ "J0" 07 + 08 8400 09 + 10 3725 E-7 11 - 12 STO 00 13 CLST 14 STO 01 15 LBL 01 16 CLX 17 86400 18 / 19 RCL 00 20 + 21 1.33964908 E-3 22 * 23 655 E-7 24 + 25 ENTER^ 26 X<> 01 27 X#Y? 28 GTO 01 29 END |
( 72 bytes / SIZE 002 )
| STACK | INPUTS | OUTPUTS |
| Y | YYYY.MNDD | / |
| X | HH.MNSS | TCB-TDB (s) |
Where the input time is expressed in TDB
Example: 3000/04/04 1h23m45s TDB
3000.0404 ENTER^
1.2345
XEQ "TCB" >>>> 500.6752393 seconds
References:
[1] Robin M. Green - "Spherical Astronomy" - Cambridge University
Press - ISBN 0-521-31779-7
[2] "Introduction aux Ephemerides Astronomiques" - EDP Sciences - ISBN
2-86883-298-9 ( in French )
[3] Fairhead & Bretagnon - "An Analytica Formula for the
Time Transformation TB-TT" Astronomy & Astrophysics 229, 240-247 (
1990 )
[4] http://www.imcce.fr/inpop
[5] IAU 2006 Resolution B3